MacFormat 2000 July/macformat-092.iso/MacFormat 92 CD/Shareware Plus/Utilities/FolderSynchronizer 1.8.9/FoldersSynchronizer/FoldersSynchronizer.9/AllScripts_1_Start.ls

Text File | 2000-05-10 | 4.9 KB | 211 lines

on Start_______________________
end

on startMovie
  cursor(4)
  set the exitLock to 1
  InitSeparator()
  InitVariabili()
  InitXTRAs()
  InitFolders()
  InitFilters()
  InitMulti()
  InitTimer()
  LookRegistration()
  InitMonitor()
  InitWindows()
  InitAppleScript()
  if not (the optionDown) then
    LeggiPreferenze()
  else
    beep()
  end if
  if the commandDown then
    EliminaStartAndQuit()
  end if
  InitMenu()
  CheckSyncButton()
  CheckOneDirection()
  SetMenuCredits()
  cursor(-1)
end

on InitVariabili
  global gSourceFolder, gDestFolder, gRememberFolders, gTopFolder, gBottomFolder, gBeepWhenDone, gSaveLogFile, gInvisible, gUnlockFile, gNero, gBianco, gGrigio, gViola, gArancio, gBlu, gThisVersion, gOneDirection, gDestructive, gOnErrorDo, gAskConfirm, gShortFlag, gShortReportList, gLogPathList, gShowPage, gTempDoAndQuit, gDoAndQuit, gJustLaunched
  set gThisVersion to "1.8.9"
  set gNero to the foreColor of member "Nero"
  set gBianco to the foreColor of member "Bianco"
  set gGrigio to the foreColor of field "Grigio"
  set gViola to the foreColor of field "Viola"
  set gArancio to the foreColor of field "Arancio"
  set gBlu to the foreColor of field "Blu"
  set gSourceFolder to EMPTY
  set gDestFolder to EMPTY
  set gTopFolder to EMPTY
  set gBottomFolder to EMPTY
  set gRememberFolders to 0
  set gOneDirection to 0
  set gDestructive to 0
  set gBeepWhenDone to 0
  set gSaveLogFile to 1
  set gInvisible to 0
  set gUnlockFile to 0
  set gOnErrorDo to 0
  set gAskConfirm to 1
  set gShortFlag to 1
  set gShortReportList to []
  set gLogPathList to []
  set gShowPage to 0
  set gDoAndQuit to 0
  set gTempDoAndQuit to 0
  set gJustLaunched to 1
  put " " into field "fSourceFolder"
  put " " into field "fDestFolder"
  put " " into field "fItems"
  set the foreColor of member "P4" to gGrigio
  updateStage()
end

on EliminaStartAndQuit
  global gDoAndQuit
  set gDoAndQuit to 0
  beep()
end

on Esci
  global gRegisteredCopy, gNero
  SetMenuCredits()
  ScriviFilePreference()
  updateStage()
  if gRegisteredCopy = 0 then
    if (the frameLabel = "Lista") or (the frameLabel = "Info") then
      puppetTransition("TranDx")
    end if
    set the foreColor of field "VersionField" to gNero
    set the textStyle of field "VersionField" to "plain"
    go("Uscita")
    repeat while the mouseUp
      nothing()
    end repeat
  end if
  clearGlobals()
  closeXLib()
  quit()
end

on stopMovie
  global gSourceFolder, gDestFolder, gGrigio, gNero, gOneDirection
  ScriviFilePreference()
  set the foreColor of member "P4" to gGrigio
  if gOneDirection then
    put "BackUp" into field "P4"
  else
    put "Synchronize" into field "P4"
  end if
  set gSourceFolder to EMPTY
  set gDestFolder to EMPTY
  put " " into field "fSourceFolder"
  put " " into field "fDestFolder"
  put " " into field "fItems"
  put " " into field "VersionField"
  if the frameLabel = "Lista" then
    set the locV of sprite 8 to 142
    set the locV of sprite 2 to -1500
    set the locV of sprite 3 to -1500
    set the locV of sprite 4 to -1500
  end if
  clearGlobals()
  set the windowList to []
  updateStage()
end

on VaiAlButton myButton, myLinea
  case myButton of
    "ScanFolder1":
      AskForSourceFolder()
    "ScanFolder2":
      AskForDestFolder()
    "Info":
      GoPreferences()
    "Filters0", "Filters1":
      GoFilters()
    "Freccia1":
      ShowReportWindow()
    "Freccia0":
      CloseReportWindow()
    "fOnOffList":
      SetOneFilterOnOff(myLinea)
    "fTypeList":
      AskForType(myLinea)
    "fCreatorList":
      AskForCreator(myLinea)
    "PickFile":
      AskForTypeAndCreator(myLinea)
    "fOperatorList":
      AskForOperatorList(myLinea)
    "fDateList":
      AskForDate(myLinea)
    "CancelFiltri":
      GoLista()
    "ApplyFiltri":
      ApplyFiltri()
    "Trash":
      case the frameLabel of
        "Filters":
          AskDeleteAllFilters()
        "Multi":
          AskDeleteAllMulti()
        "Timing":
          AskDeleteAllTimer()
      end case
    "fOnOffMulti":
      SetOneMultipleOnOff(myLinea)
    "fSourceList":
      AskForOneMultipleSource(myLinea)
    "fDestList":
      AskForOneMultipleDest(myLinea)
    "SaveMulti":
      SaveListaMulti()
    "LoadMulti":
      LoadListaMulti()
    "ApplyMulti":
      ApplyMulti()
    "Timer0", "Timer1":
      GoTimer()
    "fOnOffTimer":
      SetOneTimerOnOff(myLinea)
    "fHourList":
      AskForHour(myLinea)
    "fDayList":
      AskForDay(myLinea)
    "ApplyTimer":
      ApplyTimer()
  end case
end

on GoLista
  if the frameLabel <> "Lista" then
    set the keyDownScript to EMPTY
    if the frameLabel = "Start" then
      puppetTransition("TranDx")
    else
      puppetTransition("TranSx")
    end if
    go("Lista")
    SetMenuLista()
  end if
end

on GoPreferences
  go("Info")
  SetMenuCredits()
end

on GoCredits
  if (the frameLabel = "Lista") or (the frameLabel = "Info") then
    puppetTransition("TranDx")
  end if
  go("Credits")
  SetMenuCredits()
end